alqages/flake.nix

{
  description = "Alqages, packages from alqueva to here.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  };

  outputs = inputs @ {
    self,
    nixpkgs,
  }: let
    eachSystem = f:
      nixpkgs.lib.genAttrs ["x86_64-linux" "aarch64-linux"] (system:
        f {
          pkgs = nixpkgs.legacyPackages.${system};
        });
    filterAttrs = f: attrs: let
      names = builtins.attrNames attrs;
      filtered = builtins.filter (n: f n attrs.${n}) names;
    in
      builtins.listToAttrs (
        map (
          name: {
            inherit name;
            value = attrs.${name};
          }
        )
        filtered
      );
  in {
    overlays.default = _: prev: (builtins.listToAttrs (
      builtins.map (
        name: {
          inherit name;
          value = prev.callPackage ./packages/${name} {inherit inputs;};
        }
      ) (builtins.attrNames (
        filterAttrs (
          _: v: v == "directory"
        ) (builtins.readDir ./packages)
      ))
    ));

    packages = eachSystem ({pkgs}: self.overlays.default pkgs pkgs);
    formatter = eachSystem ({pkgs}: pkgs.alejandra);
  };
}