alqages/flake.nix

{
  description = "Alqages, packages from alqueva to here.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  };

  outputs = {
    self,
    nixpkgs,
  }: let
    eachSystem = f:
      nixpkgs.lib.genAttrs ["x86_64-linux" "aarch64-linux"] (system:
        f {
          pkgs = nixpkgs.legacyPackages.${system};
        });
  in {
    overlays.default = final: prev: let
      packages = {
        amadaluzian-neovide = prev.callPackage ./amadaluzian-neovide {};
        amadaluzian-starship = prev.callPackage ./amadaluzian-starship {};
        amadaluzian-xonsh = prev.callPackage ./amadaluzian-xonsh {inherit (packages) amadaluzian-starship;};
        amadaluzian-nu = prev.callPackage ./amadaluzian-nu {inherit (packages) amadaluzian-starship;};
        fairfax = prev.callPackage ./fairfax {};
        river-bedload = prev.callPackage ./river-bedload {};
        tela-circle-icon-theme = prev.callPackage ./tela-circle-icon-theme-patched {};
        nicotine-plus-libadwaita = prev.symlinkJoin {
          name = "nicotine";
          paths = [prev.nicotine-plus];
          nativeBuildInputs = [prev.makeWrapper];
          postBuild = ''
            wrapProgram $out/bin/nicotine \
              --set-default NICOTINE_LIBADWAITA 1
          '';
        };
        colloid-icon-theme-git = prev.colloid-icon-theme.overrideAttrs (_finalAttrs: {
          version = "master";
          src = prev.fetchFromGitHub {
            owner = "vinceliuice";
            repo = "Colloid-icon-theme";
            rev = "main";
            hash = "sha256-x2SSaIkKm1415avO7R6TPkpghM30HmMdjMFUUyPWZsk=";
          };
        });
        rose-pine-gtk-theme-git = prev.rose-pine-gtk-theme.overrideAttrs (_finalAttrs: {
          version = "master";
          src = prev.fetchFromGitHub {
            owner = "rose-pine";
            repo = "gtk";
            tag = "master";
            hash = "sha256-vCWs+TOVURl18EdbJr5QAHfB+JX9lYJ3TPO6IklKeFE=";
          };
        });
        vesktop-electron32 = prev.vesktop.override {
          electron = prev.electron_32;
        };
      };
    in
      packages;

    packages = eachSystem ({pkgs}: self.overlays.default pkgs pkgs);
    formatter = eachSystem ({pkgs}: pkgs.alejandra);
  };
}