{
  description = "My NixOS config flake";
  outputs = inputs: let
    pkgs = inputs.nixpkgs.legacyPackages.x86_64-linux;
    eachSystem = inputs.nixpkgs.lib.genAttrs (import inputs.systems);
    pkgsFor = inputs.nixpkgs.legacyPackages;
  in {
    nixosConfigurations = import ./hosts inputs;

    devShells.x86_64-linux.default = pkgs.callPackage ./shell.nix {};

    formatter.x86_64-linux = pkgs.alejandra;

    packages = eachSystem (
      system: {
        inherit (import ./packages pkgsFor.${system}) fish helix kakoune;
      }
    );

    apps = eachSystem (system: let
      inherit (inputs.self.packages.${system}) fish helix;
    in {
      default = {
        type = "app";
        program = "${fish}/bin/fish";
      };
      helix = {
        type = "app";
        program = "${helix}/bin/hx";
      };
    });
  };
  inputs = {
    # Unstable nixpkgs baby!
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    systems.url = "github:nix-systems/default-linux";

    impermanence.url = "github:nix-community/impermanence";

    schizofox.url = "github:schizofox/schizofox";

    # secure booting
    lanzaboote = {
      url = "github:nix-community/lanzaboote";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    hyprland = {
      url = "github:hyprwm/hyprland";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.systems.follows = "systems";
    };
  };
}