added stuff

nyx/modules/options/usrEnv/programs/default.nix

@@ -0,0 +1,8 @@
+{
+  imports = [
+    ./gaming.nix
+    ./launchers.nix
+    ./lockers.nix
+    ./media.nix
+  ];
+}

nyx/modules/options/usrEnv/programs/gaming.nix

@@ -0,0 +1,19 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.options) mkEnableOption;
+  inherit (config) modules;
+
+  sys = modules.system;
+  prg = sys.programs;
+in {
+  options.modules.usrEnv.programs.gaming = {
+    enable = mkEnableOption "userspace gaming programs" // {default = prg.gaming.enable;};
+    emulation.enable = mkEnableOption "programs required to emulate other platforms" // {default = prg.gaming.enable;};
+    minecraft.enable = mkEnableOption "Minecraft launcher & JDKs" // {default = prg.gaming.enable;};
+    chess.enable = mkEnableOption "Chess programs and engines" // {default = prg.gaming.enable;};
+    mangohud.enable = mkEnableOption "MangoHud overlay" // {default = prg.gaming.enable;};
+  };
+}

nyx/modules/options/usrEnv/programs/launchers.nix

@@ -0,0 +1,9 @@
+{lib, ...}: let
+  inherit (lib.options) mkEnableOption;
+in {
+  options.modules.usrEnv.programs.launchers = {
+    anyrun.enable = mkEnableOption "anyrun application launcher";
+    rofi.enable = mkEnableOption "rofi application launcher";
+    tofi.enable = mkEnableOption "tofi application launcher";
+  };
+}

nyx/modules/options/usrEnv/programs/lockers.nix

@@ -0,0 +1,27 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib.types) package;
+  inherit (lib.options) mkEnableOption mkOption;
+
+  cfg = config.modules.usrEnv.programs.screenlock;
+  pkg =
+    if cfg.gtklock.enable
+    then pkgs.gtklock
+    else pkgs.swaylock-effects;
+in {
+  options.modules.usrEnv.programs.screenlock = {
+    gtklock.enable = mkEnableOption "gtklock screenlocker";
+    swaylock.enable = mkEnableOption "swaylock screenlocker";
+
+    package = mkOption {
+      type = package;
+      default = pkg;
+      readOnly = true;
+      description = "The screenlocker package";
+    };
+  };
+}

nyx/modules/options/usrEnv/programs/media.nix

@@ -0,0 +1,63 @@
+{
+  inputs',
+  config,
+  pkgs,
+  lib,
+  ...
+}: let
+  inherit (lib) mkEnableOption mkOption types literalExpression;
+in {
+  options.modules.usrEnv.programs.media = {
+    addDefaultPackages = mkOption {
+      type = types.bool;
+      default = true;
+      description = ''
+        Whether to enable the default list of media-related packages ranging from audio taggers
+        to video editors.
+      '';
+    };
+
+    extraPackages = mkOption {
+      type = with types; listOf package;
+      default = [];
+      description = ''
+        Additional packages that will be appended to media related packages.
+      '';
+    };
+
+    ncmpcpp.enable = mkEnableOption "ncmpcpp TUI music player";
+
+    beets.enable =
+      mkEnableOption ''
+        beets media library system.
+
+
+        Will be enabled automatically if  {option}`config.modules.usrEnv.services.mpd.enabled`
+        is set to true
+      ''
+      // {default = config.modules.usrEnv.services.media.mpd.enable;};
+
+    mpv = {
+      enable = mkEnableOption "mpv media player";
+      scripts = mkOption {
+        type = with types; listOf package;
+        description = "A list of MPV scripts that will be enabled";
+        example = literalExpression ''[ pkgs.mpvScripts.cutter ]'';
+        default = with pkgs.mpvScripts; [
+          # from nixpkgs
+          cutter # cut and automatically concat videos
+          mpris # MPRIS plugin
+          thumbnail # OSC seekbar thumbnails
+          thumbfast # on-the-fly thumbnailer
+          sponsorblock # skip sponsored segments
+          uosc # proximity UI
+          quality-menu # ytdl-format quality menu
+          seekTo # seek to spefici pos.
+
+          # from nyxpkgs
+          inputs'.nyxpkgs.packages.mpv-history # save a history of played files with timestamps
+        ];
+      };
+    };
+  };
+}