chore(solterra): rename python to solterra

python is not a good hostname, subaru cars are better.

hosts/solterra/theme.nix

@@ -0,0 +1,56 @@
+{
+  pkgs,
+  config,
+  ...
+}: let
+  themes = {
+    # gtk-theme = pkgs.everforest-gtk-theme;
+    gtk-theme = pkgs.everforest-gtk-theme.overrideAttrs (finalAttrs: {
+      version = "0-unstable-2024-11-06";
+      src = pkgs.fetchFromGitHub {
+        owner = "Fausto-Korpsvart";
+        repo = finalAttrs.pname;
+        rev = "43cbe4f1aeba8b46e41836de4c8ea7ac398db119";
+        hash = "sha256-Z46i0Ihpzo4LhFvzKsvnzcHFzeYxJMvQmg2k6lmjGH0=";
+      };
+      nativeBuildInputs =
+        (finalAttrs.nativeBuildInputs or [])
+        ++ [
+          pkgs.sassc
+        ];
+      installPhase = ''
+        runHook preInstall
+        mkdir -p "$out"/share/{icons,themes}
+        cp -a icons/* "$out"/share/icons/
+        patchShebangs ./themes/install.sh
+        ./themes/install.sh -d "$out"/share/themes/
+        runHook postInstall
+      '';
+    });
+    icon-theme = themes.gtk-theme;
+    cursor-theme = pkgs.simp1e-cursors;
+  };
+  cfg = config.alqueva.system.dconf;
+in {
+  alqueva.system.dconf = {
+    enable = true;
+    luminosity = "dark";
+    theme = "everforest-gtk-theme-0-unstable-2024-11-06-Dark";
+    icon.theme = "Everforest-Dark";
+    cursor = {
+      size = 24;
+      theme = "Simp1e-Gruvbox-Dark";
+    };
+  };
+
+  qt = {
+    enable = true;
+    platformTheme = "gnome";
+    style = "adwaita-dark";
+  };
+
+  environment.systemPackages = builtins.attrValues themes;
+  systemd.user.tmpfiles.rules = [
+    "L+ %h/.config/gtk-4.0 - - - - ${themes.gtk-theme}/share/themes/${cfg.theme}/gtk-4.0"
+  ];
+}