alqueva/overlays/default.nix

{inputs, ...}: {
  flake.overlays.default = final: prev: {
    fairfax = final.callPackage ./derivations/fairfax.nix {};
    nicotine-plus = final.symlinkJoin {
      name = "nicotine";
      paths = [prev.nicotine-plus];
      nativeBuildInputs = [prev.makeWrapper];
      postBuild = ''
        wrapProgram $out/bin/nicotine \
          --set-default NICOTINE_LIBADWAITA 1
      '';
    };
    rose-pine-gtk-theme = prev.rose-pine-gtk-theme.overrideAttrs (prevAttrs: {
      version = "master";
      src = prev.fetchFromGitHub {
        owner = "rose-pine";
        repo = "gtk";
        rev = "master";
        hash = "sha256-vCWs+TOVURl18EdbJr5QAHfB+JX9lYJ3TPO6IklKeFE=";
      };
    });
  };
  perSystem = {
    pkgs,
    system,
    ...
  }: {
    _module.args.pkgs = import inputs.nixpkgs {
      inherit system;
      overlays = [
        inputs.self.overlays.default
      ];
    };

    packages = {
      inherit (pkgs) fairfax nicotine-plus rose-pine-gtk-theme;
    };
  };
}