alqueva/overlays/default.nix

{self, ...}: {
  flake.overlays.default = _final: prev: let
    packages = {
      amadaluzian-starship = prev.callPackage ./derivations/starship.nix {};
      amadaluzian-xonsh = prev.callPackage ./derivations/xonsh {inherit (packages) amadaluzian-starship;};
      amadaluzian-nu = prev.callPackage ./derivations/nu {inherit (packages) amadaluzian-starship;};
      fairfax = prev.callPackage ./derivations/fairfax.nix {};
      river-bedload = prev.callPackage ./derivations/river-bedload {};
      nicotine-plus = prev.symlinkJoin {
        name = "nicotine";
        paths = [prev.nicotine-plus];
        nativeBuildInputs = [prev.makeWrapper];
        postBuild = ''
          wrapProgram $out/bin/nicotine \
            --set-default NICOTINE_LIBADWAITA 1
        '';
      };
      rose-pine-gtk-theme = prev.rose-pine-gtk-theme.overrideAttrs (_prevAttrs: {
        version = "master";
        src = prev.fetchFromGitHub {
          owner = "rose-pine";
          repo = "gtk";
          rev = "master";
          hash = "sha256-vCWs+TOVURl18EdbJr5QAHfB+JX9lYJ3TPO6IklKeFE=";
        };
      });
    };
  in
    packages;
  perSystem = {pkgs, ...}: {
    packages = self.overlays.default null pkgs;
  };
}