{
  description = "Alqages, packages from alqueva to here.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  };

  outputs =
    inputs@{ self, nixpkgs }:
    let
      inherit (nixpkgs) lib;
      eachSystem =
        f:
        nixpkgs.lib.genAttrs [ "x86_64-linux" "aarch64-linux" ] (
          system:
          f {
            inherit system;
            pkgs = nixpkgs.legacyPackages.${system};
          }
        );
    in
    {
      overlays.default =
        _: prev:
        lib.pipe (builtins.readDir ./packages) [
          (lib.filterAttrs (_: v: v == "directory"))
          (lib.concatMapAttrs (
            name: _: {
              ${name} = prev.callPackage ./packages/${name} { inherit inputs; };
            }
          ))
        ];

      packages = eachSystem ({ pkgs, ... }: self.overlays.default pkgs pkgs);
      devShells = eachSystem (
        { pkgs, ... }:
        {
          default = pkgs.mkShell {
            name = "alqages-dev";
            packages = builtins.attrValues {
              inherit (pkgs)
                nil
                nixfmt
                deadnix
                statix
                ;
            };
          };
        }
      );
      formatter = eachSystem ({ pkgs, ... }: pkgs.nixfmt-rfc-style);
    };
}